Removing azapi_resource

Introduction

With v2.94, the azurerm provider has caught up a little and has its first version of the resources and data sources for the Azure Web PubSub Service. https://registry.terraform.io/providers/hashicorp/azurerm/2.94.0/docs/resources/web_pubsub

Time to switch to the native resource and clean up our temporary azapi_resource.

Starting configuration

Your main.tf file should be similar to this:

terraform {
  required_providers {
    azurerm = {
      source  = "hashicorp/azurerm"
      version = "=2.93"
    }

    azapi = {
      source  = "azure/azapi"
      version = "=0.3.0"
    }
  }
}

provider "azurerm" {
  features {}
}

provider "azapi" {}

resource "azurerm_resource_group" "azapi_labs" {
  name     = "azapi_labs"
  location = "West Europe"
}

resource "azapi_resource" "webpubsub" {
  type      = "Microsoft.SignalRService/WebPubSub@2021-10-01"
  name      = "azapi-labs-richeney"
  parent_id = azurerm_resource_group.azapi_labs.id
  location  = azurerm_resource_group.azapi_labs.location

  body = jsonencode({
    sku = {
      name = "Free_F1"
      capacity = 1
    }
  })
}

⚠️ You should have a different value for your azapi_resource.webpubsub.name.

Update the main.tf

1. Update the required azurerm version

   Update to v2.94:

   terraform {
     required_providers {
       azurerm = {
         source  = "hashicorp/azurerm"
         version = "=2.94"
       }
   
       azapi = {
         source  = "azure/azapi"
         version = "=0.3.0"
       }
     }
   }
   

2. Add the azurerm_web_pubsub resource

   Add the block for the native resource.

   resource "azurerm_web_pubsub" "webpubsub" {
     name                = "azapi-labs-richeney"
     resource_group_name = azurerm_resource_group.azapi_labs.name
     location            = azurerm_resource_group.azapi_labs.location
     sku                 = "Free_F1"
     capacity            = 1
   }
   

   ⚠️ Remember to change the name to match your existing Azure Web PubSub resource.

Upgrade the provider

Terraform does not automatically update versions.

Running terraform validate with the current v2.93 provider will display an error message saying that The provider hashicorp/azurerm does not support resource type "azurerm_web_pubsub"..

Running terraform init with no arguments will display an error including locked provider registry.terraform.io/hashicorp/azurerm 2.93.0 does not match configured version constraint 2.94.0.

1. Initialise

   Use the -upgrade switch.

   terraform init -upgrade
   

   Terraform will install azurerm v2.94.

Import the resource

Running terraform plan will show that it will create the azurerm_web_pubsub.webpubsub resource.

Running terraform apply will fail as the resource exists.

1. Get the resource ID

   id=$(az webpubsub list --resource-group azapi_labs --query [].id --output tsv)
   

2. Import the resource

   terraform import azurerm_web_pubsub.webpubsub $id
   

   The resource will be imported into state. Running terraform plan at this point will show that Terraform has a clean diff.

3. List the identifiers

   terraform state list
   

   Expected output:

   azapi_resource.webpubsub
   azurerm_resource_group.azapi_labs
   azurerm_web_pubsub.webpubsub
   

Remove the azapi_resource

1. Remove the azapi_resource block from main.tf

2. Remove from the state file

   terraform state rm azapi_resource.webpubsub
   

3. List the identifiers

   terraform state list
   

   Expected output:

   azurerm_resource_group.azapi_labs
   azurerm_web_pubsub.webpubsub
   

   Sure enough, the azapi_resource has been cleared up. We are fully azurerm native.

Running terraform plan will confirm that there are no planned changes.

Summary

You have successfully switched from an azapi_resource:

1. upgraded the provider
2. added the native resource
3. imported the resource into state
4. cleaned up the config
5. removed the azapi_resource from state

In the next lab you will use azapi_update_resource.